Long file path problem

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Long file path problem

Logged in as: Guest

arrSession:exec spGetSession 2,2,64913

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Long file path problem
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Long file path problem - 10/8/2008 5:11:28 PM

TomRiddle

Posts: 188
Score: 4
Joined: 2/7/2008
Status: offline

When users create files on the server where the length of the file path and file name together exceed 256 characters, problems occour when they try and access the file again. The trick to fix this is to map a drive further down the directory tree and then rename the problem files to something shorter.

I wrote a script to detect these problematicly long file names but ironically it appears to fall over when coming to one of these files.

I wrote it using file system object code because wmi falls over on { and ' characters.

Can anyone suggest anything or already has a script that does this?

Cheers

'Script by Tomriddle 2008
'LFND.vbs
'Long File Name Detector
 dim strShare, FileLen
 strLog="LFND.txt"    'log file name created in same folder that script is run from.
 strShare=inputbox("Enter Name of share"&vbcrlf&"Format:- \\server\share" , "Long File Name Detector")
 if strShare="" then
    msgbox "Quitting" 
    wscript.quit
 end if
 FileLen=inputbox("Enter max number of characters in file path","Long File Name Detector", 256)
 if FileLen="" then
    msgbox "Quitting" 
    wscript.quit
 end if
 ListAllFiles strShare
 ListFolders strShare
 msgbox "Done"
'--------------------------------------------------------------
Sub ListAllFiles(strPath)
 Set objFSO = CreateObject("Scripting.FileSystemObject")
 Set objFolder = objFSO.GetFolder(strPath)
 For Each objFile In objFolder.Files
    StrListPath=replace(strPath&"\"&objFile.Name, strShare, "x:")
    if int(len(StrListPath)) => int(FileLen) then
       WriteLog strLog, StrListPath, len(StrListPath)
    end if
 Next
End Sub
'--------------------------------------------------------------
sub ListFolders(strPath)
 Dim fs, f, f1, fc, s
 Set fs = CreateObject("Scripting.FileSystemObject")
 Set f = fs.GetFolder(strPath)
 Set fc = f.SubFolders
 For Each f1 in fc
    ListAllFiles strPath&"\"&f1.name
    ListFolders strPath&"\"&f1.name
 Next
end sub
'--------------------------------------------------------------

sub WriteLog(strLog, StrContent, lenStrListPath)
 Dim objFSO
 Set objFSO = CreateObject("Scripting.FileSystemObject")
 objFSO.OpenTextFile(strLog, 8, True).WriteLine lenStrListPath&vbtab&strContent
End Sub
'--------------------------------------------------------------

< Message edited by TomRiddle -- 10/8/2008 5:13:33 PM >

Post #: 1

RE: Long file path problem - 10/9/2008 12:06:40 AM

dm_4ever

Posts: 2641
Score: 46
Joined: 6/29/2006
From: Orange County, California
Status: offline

quote:

ORIGINAL: TomRiddle

I wrote it using file system object code because wmi falls over on { and ' characters.

If WMI would work for you you may look at the frequently asked stuff post which has an example of getting over { & ' in WMI queries
http://www.visualbasicscript.com/m_47117/tm.htm

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to TomRiddle)

Post #: 2

RE: Long file path problem - 10/9/2008 5:30:13 PM

TomRiddle

Posts: 188
Score: 4
Joined: 2/7/2008
Status: offline

Hi DM_4ever,

Thanks for your tip.

I have now started to rewrite the script using a RoboCopy command to generate a file containing the complete directory listing of all files on the share. Then it will be a simple thing script a report of all paths in that file that are longer than 256 char.

I tried the technique in the FAQ but just could not get it to work, if I manually type a path in with a ' in it, it works with that technique. But I punch in a path as a variable it fell over. So did not get past that. I imagine WMI would suffer the same ANSI 256 char MAX_PATH limitation. What I need is unicode version of these type of functions but could not find examples. RoboCopy is unicode compatible.

I will post the script that uses RoboCopy later and another one that uses just pure vbscript if someone can come up with unicode compatible code sample.

_________________________________________

Avada Kedavra

(in reply to dm_4ever)

Post #: 3

RE: Long file path problem - 10/9/2008 11:44:53 PM

TomRiddle

Posts: 188
Score: 4
Joined: 2/7/2008
Status: offline

Robocopy is just used here to get a listing of files as it can read past the MAX_PATH barrier

'Script by TomRiddle 2008

'LFND2.vbs
'Long File Name Detector

'Requirements: Robocopy.exe Version XP010 from the windows 2003 server resource kit 
'              http://www.microsoft.com/downloads/details.aspx?familyid=9d467a69-57ff-4ae7-96ee-b18c4790cffd&displaylang=en

Dim Count : Count=0

'log file name created in same folder that script is run from.
   strLog="LFND.txt"

'Path to Robocopy.exe 
   RobocopyEXE="C:\Program Files\Windows Resource Kits\Tools\ROBOCOPY.EXE"

'Check RoboCopy.exe is in path
   Set objFSO = CreateObject("Scripting.FileSystemObject")
   if objFSO.FileExists(RobocopyEXE) Then
   else
      msgbox "Error"&vbcrlf&"Robocopy.exe not found in path"
      wscript.quit      
   end if   
   
'Check RoboCopy Version is up to scratch
   Set objFSO = CreateObject("Scripting.FileSystemObject")
   if replace(objFSO.GetFileVersion(RobocopyEXE), ".", "")<replace("5.1.1.1010", ".", "") then
      msgbox "Error"&vbcrlf&"Script requires Robocopy.exe Version XP010 or greater"
      wscript.quit
   end if

'Create temp file name
   Set objShell=CreateObject("WScript.Shell") 
   strTempDir=objShell.ExpandEnvironmentStrings("%temp%") 
   strTempFile=strTempDir&"\"&strLog

'Input share name to scan
   strShare=inputbox("Enter Name of share"&vbcrlf&"Format:- \\server\share","Long File Name Detector", "\\Dim8400\dell")
   if strShare="" then 
      msgbox "Quitting"
      wscript.quit
   else
      LenShare=len(strShare)
   end if

'Input max number of characters - File names this long and longer will be added to the report
   LenFile=inputbox("Enter max number of characters in file path","Long File Name Detector", 256)
   if LenFile="" then 
      msgbox "Quitting"
      wscript.quit
   end if

'Append or overwrite last output file
   Set objFSO = CreateObject("Scripting.FileSystemObject")
   If objFSO.FileExists(strLog) Then
      Warning = MsgBox ("Do you want to overwrite last log file?"&vbcrlf&vbcrlf&"Yes - Overwrite"&vbcrlf&"No  - Append", 276, "File exist") 
      if Warning = 6 then 
         objFSO.DeleteFile(strLog)
         wscript.sleep(1000)
      end if   
   End If

'Run main program
   RoboScanShare strTempFile, strShare, RobocopyEXE
   LFNDOutput strTempFile, strShare, strLog, LenFile, LenShare

'Display results
   on error resume next
   msgbox "Done"&vbcrlf&"Found "&Count&" file paths "&LenFile&" characters or longer" 
   Set objShell = CreateObject("WScript.Shell") 
   objShell.Run strLog, 1, false

'Delete temp file
   Set objFSO = CreateObject("Scripting.FileSystemObject")
   objFSO.DeleteFile(strTempFile)
   on error goto 0

wscript.quit

'--------------------------------------------------------------

sub RoboScanShare(strTempFile, strShare, RobocopyEXE)

RoboScanCMD=chr(34)&RobocopyEXE&chr(34)&" "&strShare&" c: /v /e /ns /nc /fp /l /log:"&strTempFile&" /tee /njh /njs"
   Set objShell = CreateObject("WScript.Shell") 
   objShell.Run RoboScanCMD, 1, true

end sub

'--------------------------------------------------------------

sub LFNDOutput(strTempFile, strShare, strLog, LenFile, LenShare)

set oShell = CreateObject("WScript.Shell")
   oShell.Popup "Script will now create report", 5, "Long File Name Detector", vbOKOnly

LenF=LenFile+LenShare-3

Const ForReading = 1

Set objFSO = CreateObject("Scripting.FileSystemObject")
   Set objFile = objFSO.OpenTextFile(strTempFile, ForReading)

Do Until objFile.AtEndOfStream
      strLine = objFile.Readline
      strLine = LTrim(replace(strLine, vbtab, ""))

If int(Len(strLine))>int(LenF) Then
         if instr(strLine, strShare) then
            WriteLog strLog, "x:"&replace(strLine, StrShare, "")
         end if
      End If
   Loop

objFile.Close

end sub

'--------------------------------------------------------------
 
sub WriteLog(strLog, StrContent)

Dim objFSO
   Set objFSO = CreateObject("Scripting.FileSystemObject")
   objFSO.OpenTextFile(strLog, 8, True).WriteLine len(StrContent)&vbtab&strContent
   count=count+1

End Sub

'--------------------------------------------------------------

< Message edited by TomRiddle -- 10/12/2008 1:53:00 PM >

(in reply to TomRiddle)